connect.to.blog(): flash/flex/AS: 2008年9月アーカイブ

ちょい絶 5にて発表してきたので、一ヶ月ぶりのエントリーをば。

CMYKといえば普通印刷などで使われる色空間ですが、今回はそれをFlash上で再現してみる。という内容の発表をしました。

問題はRGB -> CMYK変換のアルゴリズムですが、幸いなことに詳しい理論知らなくても色の変換式がまとめられているのでそれを利用させていただきました。（参考サイト）

asの構成としては
RGB, CMYK クラス、変換を担当するColorConverterクラスというようになっています。

package  
{
	public class ColorConverter 
	{
		
		public function ColorConverter() 
		{
			
		}
		public static function hexToRgb(color:uint):RGBColor
		{
			var red:uint = (color >> 16) & 0xff;
			var green:uint = (color >> 8) & 0xff;
			var blue:uint = (color >> 0) & 0xff;
			return new RGBColor(red, green, blue);
		}
		
		public static function rgbToHex(rgb:RGBColor):uint
		{
			var hex:uint = (rgb.red << 16) + (rgb.green << 8) + rgb.blue;
			return hex;
		}
		
		public static function cmykToRgb(pColor:CMYKColor):RGBColor
		{
			var tmpC:Number = pColor.cyan / 100;
			var tmpM:Number = pColor.magenta / 100;
			var tmpY:Number = pColor.yellow / 100;
			var tmpK:Number = pColor.black / 100;
			var red:uint = Math.round((1 - Math.min(1, tmpC * (1 - tmpK) + tmpK))* 255);
			var green:uint = Math.round((1 - Math.min(1, tmpM * (1 - tmpK) + tmpK))* 255);
			var blue:uint = Math.round((1 - Math.min(1, tmpY * (1 - tmpK) + tmpK)) * 255);
			var rgb:RGBColor = new RGBColor(red, green, blue);
			return rgb;
		}
		public static function rgbToCmyk(rgb:RGBColor):CMYKColor
		{
			var tmpR:Number = rgb.red / 255;
			var tmpG:Number = rgb.green / 255;
			var tmpB:Number = rgb.blue / 255;
			var cyan:Number;
			var magenta:Number;
			var yellow:Number;
			var black:Number;
			if (tmpR == 0 && tmpG == 0 && tmpR == 0)
			{
				cyan = 0;
				magenta = 0;
				yellow = 0;
				black = 100;
			}
			else
			{
				var tmpBk:Number = Math.min(1 - tmpR, 1 - tmpG, 1 - tmpB);
				cyan = (1 - tmpR - tmpBk) / (1 - tmpBk) * 100;
				magenta = (1 - tmpG - tmpBk) / (1 - tmpBk) * 100;
				yellow = (1 - tmpB - tmpBk) / (1 - tmpBk) * 100;
				black = tmpBk * 100;
			}
			return new CMYKColor (cyan, magenta, yellow, black);
		}
		
		public static function hexToCmyk(color:uint):CMYKColor
		{
			return rgbToCmyk(hexToRgb(color));
		}
		
		public static function cmykToHex(pColor:CMYKColor):uint
		{
			return rgbToHex(cmykToRgb(pColor));
		}
		
	}
	
}

最初に書いた処理は getpixel()で1ドットずつcolorをとってColorConverterで変換し、
と言うような書き方をしていました。明らかに重そうなコードですが、実際に自宅のデスクトップ機で3.8秒ぐらい、penM1.1なx40だと7秒近くも処理時間がかかります；；さすがに遅すぎなのでなんとか改善してみたのが下記のコード。

package 
{
	import flash.display.Bitmap;
	import flash.display.BitmapData;
	import flash.display.Sprite;
	import flash.utils.ByteArray;
	import flash.utils.getTimer;
	
	public class Main1 extends Sprite
	{
		[Embed(source='DSCF0893.jpg')]
		private var Image1:Class;
		public function Main1():void
		{
			init();
		}
		private function init():void
		{
			var bitmap:Bitmap = new Image1();
			addChild(bitmap);
			
			var bitmapData:BitmapData = bitmap.bitmapData;
			var w:int = bitmapData.width;
			var h:int = bitmapData.height;
			
			var tmpT:int = getTimer();
			
			var bitmapData2:BitmapData = new BitmapData(w, h, false);
			var bytes:ByteArray = bitmapData.getPixels(bitmapData.rect);
			var num:uint = bytes.length;
			var cmyk:CMYKColor;
			var rgb:RGBColor = new RGBColor();
			var i:int;
			for (i = 0; i < num; )
			{
				i++;
				rgb.red = bytes[i++];
				rgb.green = bytes[i++];
				rgb.blue = bytes[i++];
				cmyk = ColorConverter.rgbToCmyk(rgb);
				cmyk.cyan = 0;
				cmyk.yellow = 0;
				cmyk.black = 0;
				rgb = ColorConverter.cmykToRgb(cmyk);
				i -= 3;
				bytes[i++] = rgb.red;
				bytes[i++] = rgb.green;
				bytes[i++] = rgb.blue;
			}
			bytes.position = 0;
			bitmapData2.lock();
			bitmapData2.setPixels(bitmapData.rect, bytes);
			bitmapData2.unlock();
			
			trace((getTimer() - tmpT) + "msec");
			
			var bitmap2:Bitmap = new Bitmap(bitmapData2);
			bitmap2.x = 500;
			addChild(bitmap2);
		}
	}
}

最初の書き方と比べると30%ほど速くはなりました。x40だとまだ5秒台ですが...もっと速くできないとなあ。。

actionscriptでcmykの続きを読む

flash/flex/AS: 2008年9月アーカイブ

flex3の和書

actionscriptでcmyk

iddy

検索

カテゴリ

最近のブログ記事